Function LaatsteRij()

LaatsteRij (functie)

Dit artikel beschrijft de syntax en het gebruik van de VBA functie LaatsteRij.

Omschrijving

Het komt bij het ontwikkelen van Excelmaatwerk regelmatig voor dat je - bijvoorbeeld voor het onderaan toevoegen van waarden - in een kolom of werkblad de laatste met waarden gevulde rij wilt bepalen. De numerieke waarde die wordt teruggegeven representeert het rijnummer die voor verdere verwerking kan worden gebruikt.

Syntax

LaatsteRij(KolomNummer, Werkblad)

De LaatsteRij functie heeft de volgende verplichte parameters:

Kolomnummer Optioneel. Alfa-numeriek karakter (cijfer of letter) die de kolom representeert waarvan de laatst gevulde rij moet worden bepaald.
Werkblad  Optioneel. Werkblad-object 

Code


Function LaatsteRij(Optional Kolom As Variant, Optional sh As Variant) As Long
 
    Dim ZoekBereik As String
    ZoekBereik = ""
 
    On Error Resume Next
    If IsMissing(sh) Then Set sh = ActiveSheet
    If IsMissing(Kolom) Then
        LaatsteRij = sh.Cells.Find(What:="*", _
                            after:=sh.Range("A1"), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
    Else
'       Eerst i.g.v. numerieke kolomrepresentatie deze omzetten naar een tekstuele kolomwaarde
        If IsNumeric(Kolom) Then
            ZoekBereik = sh.Columns(Kolom).Address
        Else
            ZoekBereik = Kolom & ":" & Kolom
        End If
 
        LaatsteRij = sh.Range(ZoekBereik).Find(What:="*", _
                            after:=sh.Range(ZoekBereik).Cells(1, 1), _
                            Lookat:=xlPart, _
                            LookIn:=xlFormulas, _
                            SearchOrder:=xlByRows, _
                            SearchDirection:=xlPrevious, _
                            MatchCase:=False).Row
    End If
    On Error GoTo 0
End Function
 

Voorbeeld


lngLaatsteRij = LaatsteRij()
lngLaatsteRij = LaatsteRij("B")
lngLaatsteRij = LaatsteRij(2)
lngLaatsteRij = LaatsteRij(2, Worksheets("Blad1"))
 

 
U kunt bovenstaande VBA code gebruiken en naar eigen wens aanpassen. TemplateBuilding accepteert geen aansprakelijkheid voor het kopiëren, aanpassen en het gebruik van hiervoorgenoemde VBA code.

Read 2448 times
Inloggen

Inloggen

Mrah Development BV

MRAHDevelopment

Mrah Development BV
Voor uw Excel vragen,
Leuke gratis Excel toepassingen.

ExcelFIX

links_partners_5

ExcelFIX
ExcelFIX herstelt beschadigde
en corrupte spreadsheets die
gemaakt zijn in Microsoft Excel.

Infotron BV


linkspartners_5

www.infotron.nl
Zelf al goed met Excel, maar wilt u bestanden beter begrijpen, valideren en verbeteren?

Exhelp.be

Links_partners_20

ExcelFIX
Dé Vlaamse Excel blog